X rdb-queries-results-q1:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $i in $items//item_tuple where $i/start_date <= xs:date("1999-01-31") and $i/end_date >= xs:date("1999-01-31") and contains(exactly-one($i/description), "Bicycle") order by $i/itemno return <item_tuple> { $i/itemno } { $i/description } </item_tuple> } </result>

 X rdb-queries-results-q2:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $i in $items//item_tuple let $b := $bids//bid_tuple[itemno = $i/itemno] where contains(exactly-one($i/description), "Bicycle") order by $i/itemno return <item_tuple> { $i/itemno } { $i/description } <high_bid>{ max($b/bid) }</high_bid> </item_tuple> } </result>

 X rdb-queries-results-q3:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $u in $users//user_tuple for $i in $items//item_tuple where $u/rating > "C" and $i/reserve_price > 1000 and $i/offered_by = $u/userid return <warning> { $u/name } { $u/rating } { $i/description } { $i/reserve_price } </warning> } </result>

 X rdb-queries-results-q4:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $i in $items//item_tuple where empty ($bids//bid_tuple[itemno = $i/itemno]) return <no_bid_item> { $i/itemno } { $i/description } </no_bid_item> } </result>

 X rdb-queries-results-q5:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { unordered ( for $seller in $users//user_tuple, $buyer in $users//user_tuple, $item in $items//item_tuple, $highbid in $bids//bid_tuple where $seller/name = "Tom Jones" and $seller/userid = $item/offered_by and contains(exactly-one($item/description), "Bicycle") and $item/itemno = $highbid/itemno and $highbid/userid = $buyer/userid and $highbid/bid = max( $bids//bid_tuple [itemno = $item/itemno]/bid ) return <jones_bike> { $item/itemno } { $item/description } <high_bid>{ $highbid/bid }</high_bid> <high_bidder>{ $buyer/name }</high_bidder> </jones_bike> ) } </result>

 X rdb-queries-results-q6:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $item in $items//item_tuple let $b := $bids//bid_tuple[itemno = $item/itemno] let $z := max($b/bid) where exactly-one($item/reserve_price) * 2 < $z return <successful_item> { $item/itemno } { $item/description } { $item/reserve_price } <high_bid>{$z }</high_bid> </successful_item> } </result>

 X rdb-queries-results-q7:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: let $allbikes := $items//item_tuple [contains(exactly-one(description), "Bicycle") or contains(exactly-one(description), "Tricycle")] let $bikebids := $bids//bid_tuple[itemno = $allbikes/itemno] return <high_bid> { max($bikebids/bid) } </high_bid>

 X rdb-queries-results-q8:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: let $item := $items//item_tuple [end_date >= xs:date("1999-03-01") and end_date <= xs:date("1999-03-31")] return <item_count> { count($item) } </item_count>

 X rdb-queries-results-q9:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { let $end_dates := $items//item_tuple/end_date for $m in distinct-values( for $e in $end_dates return month-from-date($e)) let $item := $items//item_tuple[year-from-date(exactly-one(end_date)) = 1999 and month-from-date(exactly-one(end_date)) = $m] order by $m return <monthly_result> <month>{ $m }</month> <item_count>{ count($item) }</item_count> </monthly_result> } </result>

 X rdb-queries-results-q10:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $highbid in $bids//bid_tuple, $user in $users//user_tuple where $user/userid = $highbid/userid and $highbid/bid = max($bids//bid_tuple[itemno=$highbid/itemno]/bid) order by exactly-one($highbid/itemno) return <high_bid> { $highbid/itemno } { $highbid/bid } <bidder>{ $user/name/text() }</bidder> </high_bid> } </result>

 X rdb-queries-results-q11:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: let $highbid := max($bids//bid_tuple/bid) return <result> { for $item in $items//item_tuple, $b in $bids//bid_tuple[itemno = $item/itemno] where $b/bid = $highbid return <expensive_item> { $item/itemno } { $item/description } <high_bid>{ $highbid }</high_bid> </expensive_item> } </result>

 X rdb-queries-results-q12:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: declare function local:bid_summary() as element()* { for $i in distinct-values($bids//itemno) let $b := $bids//bid_tuple[itemno = $i] return <bid_count> <itemno>{ $i }</itemno> <nbids>{ count($b) }</nbids> </bid_count> }; <result> { let $bid_counts := local:bid_summary(), $maxbids := max($bid_counts/nbids), $maxitemnos := $bid_counts[nbids = $maxbids] for $item in $items//item_tuple, $bc in $bid_counts where $bc/nbids = $maxbids and $item/itemno = $bc/itemno return <popular_item> { $item/itemno } { $item/description } <bid_count>{ $bc/nbids/text() }</bid_count> </popular_item> } </result>

 X rdb-queries-results-q13:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $uid in distinct-values($bids//userid), $u in $users//user_tuple[userid = $uid] let $b := $bids//bid_tuple[userid = $uid] order by exactly-one($u/userid) return <bidder> { $u/userid } { $u/name } <bidcount>{ count($b) }</bidcount> <avgbid>{ avg($b/bid) }</avgbid> </bidder> } </result>

 X rdb-queries-results-q14:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $i in distinct-values($items//itemno) let $b := $bids//bid_tuple[itemno = $i] let $avgbid := avg($b/bid) where count($b) >= 3 order by $avgbid descending return <popular_item> <itemno>{ $i }</itemno> <avgbid>{ $avgbid }</avgbid> </popular_item> } </result>

 X rdb-queries-results-q15:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $u in $users//user_tuple let $b := $bids//bid_tuple[userid=$u/userid and bid>=100] where count($b) > 1 return <big_spender>{ $u/name/text() }</big_spender> } </result>

 X rdb-queries-results-q16:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $u in $users//user_tuple let $b := $bids//bid_tuple[userid = $u/userid] order by exactly-one($u/userid) return <user> { $u/userid } { $u/name } { if (empty($b)) then <status>inactive</status> else <status>active</status> } </user> } </result>

 X rdb-queries-results-q17:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <frequent_bidder> { for $u in $users//user_tuple where every $item in $items//item_tuple satisfies some $b in $bids//bid_tuple satisfies ($item/itemno = $b/itemno and $u/userid = $b/userid) return $u/name } </frequent_bidder>

 X rdb-queries-results-q18:

Created on: 2005-02-03
Spec Dependencies:
spec = XQ10+
spec = XQ10+

Test: <result> { for $u in $users//user_tuple order by $u/name return <user> { $u/name } { for $b in distinct-values($bids//bid_tuple [userid = $u/userid]/itemno) for $i in $items//item_tuple[itemno = $b] let $descr := $i/description/text() order by exactly-one($descr) return <bid_on_item>{ $descr }</bid_on_item> } </user> } </result>